/*****************************************************************************
Champion Right-Clicker settings:
  Double right-click on the ground to equip a different -ite.
  Right-click on another player to pull them.
  Double right-click on yourself to switch between your Fell Blade and your
    normal weapon, or to rearm yourself if a chain is equipped.
  Spin your mouse wheel up to equip/use a chain.
  Spin your mouse wheel down to disarm or rearm.

You must edit the variables gRC_ite and gRC_swap_fell below to let the macro
know which -ites you will be using and which weapon to swap your Fell with by
default.  You can either edit these variables here in this macro file, or copy
and paste them into your Champion character's macro file.
*****************************************************************************/

// Set this to the weapon that your Fell Blade will be swapped with by default.
// When you equip your Fell, this variable will be changed to the item you have
// equipped at the time, however this variable must be set ahead of time in
// case you log on with your Fell equipped.
setglobal gRC_swap_fell "greatsword"

// Enter in a list of -ites you're able to use into the array below.
// Set any remaining array values to blank ("").
// Include "Pauldron" in the -ite names if you're qualified to use pauldrons.
setglobal gRC_ite[0] "Atkite Pauldron"
setglobal gRC_ite[1] "Darkite Pauldron"
setglobal gRC_ite[2] ""
setglobal gRC_ite[3] ""

RC_champion_setup
{
message "* Using Champion right-click settings."

setglobal gRC_init 1	// Lets the Right-Clicker know that settings have been initialized.  Don't change this.

setglobal gRC_item "chain"		// This set's special ITEM.
setglobal gRC_item_slot "right"		// The SLOT this item is equipped in (right, left, neck, finger, shoulders, selected, etc).

// Actions without special item equipped:
setglobal gRC_right_click_ground "0"		// Action called on SINGLE right-click on GROUND.
setglobal gRC_double_right_click_ground "RC_swap_ite"		// Action called on DOUBLE right-click on GROUND.

setglobal gRC_right_click_player "RC_pull"		// Action called on SINGLE right-click on ANOTHER PLAYER.
setglobal gRC_double_right_click_player "0"		// Action called on DOUBLE right-click on ANOTHER PLAYER.

setglobal gRC_right_click_self "0"		// Action called on SINGLE right-click on YOURSELF.
setglobal gRC_double_right_click_self "RC_swap_fell"		// Action called on DOUBLE right-click on YOURSELF.

setglobal gRC_wheel_up "RC_use_chain"		// Action called on WHEEL ticks UP.
setglobal gRC_wheel_up_cooldown 0		// Set this to 1 to have this action have a COOLDOWN (cannot call more than once per spin of the wheel).

setglobal gRC_wheel_down "RC_toggle_disarm"		// Action called on WHEEL ticks DOWN.
setglobal gRC_wheel_down_cooldown 1		// Set this to 1 to have this action have a COOLDOWN (cannot call more than once per spin of the wheel).

// Actions with special ITEM equipped:
setglobal gRC_right_click_ground_with_item "0"	// Action called on SINGLE right-click on GROUND with special ITEM equipped.
setglobal gRC_double_right_click_ground_with_item "RC_swap_ite"	// Action called on DOUBLE right-click on GROUND with special ITEM equipped.

setglobal gRC_right_click_player_with_item "RC_pull"	// Action called on SINGLE right-click on ANOTHER PLAYER with special ITEM equipped.
setglobal gRC_double_right_click_player_with_item "0"	// Action called on DOUBLE right-click on ANOTHER PLAYER with special ITEM equipped.

setglobal gRC_right_click_self_with_item "0"	// Action called on SINGLE right-click on YOURSELF with special ITEM equipped.
setglobal gRC_double_right_click_self_with_item "RC_toggle_chain"	// Action called on DOUBLE right-click on YOURSELF with special ITEM equipped.

setglobal gRC_wheel_up_with_item "/useitem chain\r"	// Action called on WHEEL ticks UP with special ITEM equipped.
setglobal gRC_wheel_up_with_item_cooldown 0	// Set this to 1 to have this action have a COOLDOWN (cannot call more than once per spin of the wheel).

setglobal gRC_wheel_down_with_item "RC_rearm"	// Action called on WHEEL ticks DOWN with special ITEM equipped.
setglobal gRC_wheel_down_with_item_cooldown 1	// Set this to 1 to have this action have a COOLDOWN (cannot call more than once per spin of the wheel).
}



RC_swap_fell
{
if @my.right_item != "fell blade"
	if @my.right_item != "Nothing"
		if @my.right_item != "chain"
			setglobal gRC_swap_fell @my.right_item
		end if
	end if
	
	"/equip fellblade\r"
else
	"/equip \"" gRC_swap_fell "\"\r"
end if
}



RC_swap_ite
{
set ite_num 0

// Find the currently equipped ite in our list of equipable ites.
label ITECHECK
if ite_num >= 4
	// No ite equipped
	set ite_num 0
else if gRC_ite[ite_num] == ""
	// No ite equipped
	set ite_num 0
else if gRC_ite[ite_num] >= "auldron"
	// Shoulder ite
	if @my.shoulders_item != gRC_ite[ite_num]
		set ite_num + 1
		goto "ITECHECK"
	end if
	// Matching ite found
	set ite_num + 1
else
	// Left-hand ite
	if @my.left_item != gRC_ite[ite_num]
		set ite_num + 1
		goto "ITECHECK"
	end if
	// Matching ite found
	set ite_num + 1
end if

if gRC_ite[ite_num] == ""
	set ite_num 0
end if
"/equip \"" gRC_ite[ite_num] "\"\r"
}